Variables
*********

A variable is a name used in a program to stand for a value. In Lisp, each variable is represented by a Lisp symbol (see Symbols).  The variable name is simply the symbol's name, and the variable's value is stored in the symbol's value cell (To be precise, under the default dynamic scoping rule, the value cell always holds the variable's current value, but this is not the case under the lexical scoping rule.  See Variable Scoping, for details.).  See Symbol Components.  In Emacs Lisp, the use of a symbol as a variable is independent of its use as a function name.

As previously noted in this manual, a Lisp program is represented primarily by Lisp objects, and only secondarily as text.  The textual form of a Lisp program is given by the read syntax of the Lisp objects that constitute the program.  Hence, the textual form of a variable in a Lisp program is written using the read syntax for the symbol representing the variable.

Global Variables
================

The simplest way to use a variable is globally.  This means that the variable has just one value at a time, and this value is in effect (at least for the moment) throughout the Lisp system.  The value remains in effect until you specify a new one.  When a new value replaces the old one, no trace of the old value remains in the variable.

You specify a value for a symbol with setq.  For example,

     (setq x '(a b))

gives the variable x the value (a b).  Note that setq is a special form (see Special Forms); it does not evaluate its first argument, the name of the variable, but it does evaluate the second argument, the new value.

Once the variable has a value, you can refer to it by using the symbol itself as an expression.  Thus,

     x => (a b)

assuming the setq form shown above has already been executed.

If you do set the same variable again, the new value replaces the old one:

     x
          => (a b)

     (setq x 4)
          => 4

     x
          => 4

Variables that Never Change
===========================

In Emacs Lisp, certain symbols normally evaluate to themselves.  These include nil and t, as well as any symbol whose name starts with : (these are called keywords).  These symbols cannot be rebound, nor can their values be changed.  Any attempt to set or bind nil or t signals a setting-constant error.  The same is true for a keyword (a symbol whose name starts with :), if it is interned in the standard obarray, except that setting such a symbol to itself is not an error.

     nil == 'nil
          => nil

     (setq nil 500)
     error--> Attempt to set constant symbol: nil

 -- Function: keywordp object
     function returns t if OBJECT is a symbol whose name starts with :, interned in the standard obarray, and returns nil otherwise.

These constants are fundamentally different from the constants defined using the defconst special form (see Defining Variables).  A defconst form serves to inform human readers that you do not intend to change the value of a variable, but Emacs does not raise an error if you actually change it.

A small number of additional symbols are made read-only for various practical reasons.  These include enable-multibyte-characters, most-positive-fixnum, most-negative-fixnum, and a few others.  Any attempt to set or bind these also signals a setting-constant error.

Local Variables
===============

Global variables have values that last until explicitly superseded with new values.  Sometimes it is useful to give a variable a local value---a value that takes effect only within a certain part of a Lisp program.  When a variable has a local value, we say that it is locally bound to that value, and that it is a local variable.

For example, when a function is called, its argument variables receive local values, which are the actual arguments supplied to the function call; these local bindings take effect within the body of the function.  To take another example, the let special form explicitly establishes local bindings for specific variables, which take effect only within the body of the let form.

We also speak of the global binding, which is where (conceptually) the global value is kept.

Establishing a local binding saves away the variable's previous value (or lack of one).  We say that the previous value is shadowed.  Both global and local values may be shadowed.  If a local binding is in effect, using setq on the local variable stores the specified value in the local binding.  When that local binding is no longer in effect, the previously shadowed value (or lack of one) comes back.

A variable can have more than one local binding at a time (e.g., if there are nested let forms that bind the variable).  The current binding is the local binding that is actually in effect. It determines the value returned by evaluating the variable symbol, and it is the binding acted on by setq.

For most purposes, you can think of the current binding as the innermost local binding, or the global binding if there is no local binding.  To be more precise, a rule called the scoping rule determines where in a program a local binding takes effect.  The default scoping rule in Emacs Lisp is called dynamic scoping, which simply states that the current binding at any given point in the execution of a program is the most recently-created binding for that variable that still exists.  For details about dynamic scoping, and an alternative scoping rule called lexical scoping, see Variable Scoping.

The special forms let and let* exist to create local bindings:

 -- Special Form: let (bindings...) forms...
     This special form sets up local bindings for a certain set of variables, as specified by BINDINGS, and then evaluates all of the FORMS in textual order.  Its return value is the value of the last form in FORMS.  The local bindings set up by let will be in effect only within the body of FORMS.

     Each of the BINDINGS is either (i) a symbol, in which case that symbol is locally bound to nil; or (ii) a list of the form (SYMBOL VALUE-FORM), in which case SYMBOL is locally bound to the result of evaluating VALUE-FORM.  If VALUE-FORM is omitted, nil is used.

     All of the VALUE-FORMs in BINDINGS are evaluated in the order they appear and before binding any of the symbols to them. Here is an example of this: z is bound to the old value of y, which is 2, not the new value of y, which is 1.

          (setq y 2)
               => 2

          (let ((y 1)
                (z y))
            (list y z))
               => (1 2)

     On the other hand, the order of bindings is unspecified: in the following example, either 1 or 2 might be printed.

          (let ((x 1)
                (x 2))
            (print x))

     Therefore, avoid binding a variable more than once in a single let form.

 -- Special Form: let* (bindings...) forms...
     This special form is like let, but it binds each variable right after computing its local value, before computing the local value for the next variable.  Therefore, an expression in BINDINGS can refer to the preceding symbols bound in this let* form. Compare the following example with the example above for let.

          (setq y 2)
               => 2

          (let* ((y 1)
                 (z y))    ; Use the just-established value of y.
            (list y z))
               => (1 1)

 -- Special Form: letrec (bindings...) forms...
     This special form is like let*, but all the variables are bound before any of the local values are computed.  The values are then assigned to the locally bound variables.  This is only useful when lexical binding is in effect, and you want to create closures that refer to bindings that would otherwise not yet be in effect when using let*.

     For instance, here's a closure that removes itself from a hook after being run once:

          (letrec ((hookfun (lambda ()
                              (message "Run once")
                              (remove-hook 'post-command-hook hookfun))))
            (add-hook 'post-command-hook hookfun))

 -- Special Form: dlet (bindings...) forms...
     This special form is like let, but it binds all variables dynamically.  This is rarely useful---you usually want to bind normal variables lexically, and special variables (i.e., variables that are defined with defvar) dynamically, and this is what let does.

     dlet can be useful when interfacing with old code that assumes that certain variables are dynamically bound (see Dynamic Binding), but it's impractical to defvar these variables. dlet will temporarily make the bound variables special, execute the forms, and then make the variables non-special again.

 -- Special Form: named-let name bindings &rest body
     This special form is a looping construct inspired from the Scheme language.  It is similar to let: It binds the variables in BINDINGS, and then evaluates BODY.  However, named-let also binds NAME to a local function whose formal arguments are the variables in BINDINGS and whose body is BODY.  This allows BODY to call itself recursively by calling NAME, where the arguments passed to NAME are used as the new values of the bound variables in the recursive invocation.

     Example of a loop summing a list of numbers:

          (named-let sum ((numbers '(1 2 3 4))
                          (running-sum 0))
            (if numbers
                (sum (cdr numbers) (+ running-sum (car numbers)))
              running-sum))
          => 10

     Recursive calls to NAME that occur in tail positions in BODY are guaranteed to be optimized as tail calls, which means that they will not consume any additional stack space no matter how deeply the recursion runs.  Such recursive calls will effectively jump to the top of the loop with new values for the variables.

     A function call is in the tail position if it's the very last thing done so that the value returned by the call is the value of BODY itself, as is the case in the recursive call to sum above.

Here is a complete list of the other facilities that create local bindings:

  * Function calls (see Functions).

  * Macro calls (see Macros).

  * condition-case (see Errors).

Variables can also have buffer-local bindings (see Buffer-Local Variables); a few variables have terminal-local bindings (see Multiple Terminals).  These kinds of bindings work somewhat like ordinary local bindings, but they are localized depending on where you are in Emacs.

When a Variable is Void
=======================

We say that a variable is void if its symbol has an unassigned value cell (see Symbol Components).

Under Emacs Lisp's default dynamic scoping rule (see Variable Scoping), the value cell stores the variable's current (local or global) value.  Note that an unassigned value cell is not the same as having nil in the value cell.  The symbol nil is a Lisp object and can be the value of a variable, just as any other object can be; but it is still a value.  If a variable is void, trying to evaluate the variable signals a void-variable error, instead of returning a value.

Under the optional lexical scoping rule, the value cell only holds the variable's global value---the value outside of any lexical binding construct.  When a variable is lexically bound, the local value is determined by the lexical environment; hence, variables can have local values even if their symbols' value cells are unassigned.

 -- Function: makunbound symbol
     This function empties out the value cell of SYMBOL, making the variable void.  It returns SYMBOL.

     If SYMBOL has a dynamic local binding, makunbound voids the current binding, and this voidness lasts only as long as the local binding is in effect.  Afterwards, the previously shadowed local or global binding is reexposed; then the variable will no longer be void, unless the reexposed binding is void too.

     Here are some examples (assuming dynamic binding is in effect):

          (setq x 1)               ; Put a value in the global binding.
               => 1
          (let ((x 2))             ; Locally bind it.
            (makunbound 'x)        ; Void the local binding.
            x)
          error--> Symbol's value as variable is void: x

          x                        ; The global binding is unchanged.
               => 1

          (let ((x 2))             ; Locally bind it.
            (let ((x 3))           ; And again.
              (makunbound 'x)      ; Void the innermost-local binding.
              x))                  ; And refer: it's void.
          error--> Symbol's value as variable is void: x

          (let ((x 2))
            (let ((x 3))
              (makunbound 'x))     ; Void inner binding, then remove it.
            x)                     ; Now outer let binding is visible.
               => 2

 -- Function: boundp variable
     This function returns t if VARIABLE (a symbol) is not void, and nil if it is void.

     Here are some examples (assuming dynamic binding is in effect):

          (boundp 'abracadabra)          ; Starts out void.
               => nil

          (let ((abracadabra 5))         ; Locally bind it.
            (boundp 'abracadabra))
               => t

          (boundp 'abracadabra)          ; Still globally void.
               => nil

          (setq abracadabra 5)           ; Make it globally nonvoid.
               => 5

          (boundp 'abracadabra)
               => t

Defining Global Variables
=========================

A variable definition is a construct that announces your intention to use a symbol as a global variable.  It uses the special forms defvar or defconst, which are documented below.

A variable definition serves three purposes.  First, it informs people who read the code that the symbol is intended to be used a certain way (as a variable).  Second, it informs the Lisp system of this, optionally supplying an initial value and a documentation string.  Third, it provides information to programming tools such as etags, allowing them to find where the variable was defined.

The difference between defconst and defvar is mainly a matter of intent, serving to inform human readers of whether the value should ever change.  Emacs Lisp does not actually prevent you from changing the value of a variable defined with defconst.  One notable difference between the two forms is that defconst unconditionally initializes the variable, whereas defvar initializes it only if it is originally void.

To define a customizable variable, you should use defcustom (which calls defvar as a subroutine).  See Variable Definitions.

 -- Special Form: defvar symbol [value [doc-string]]
     This special form defines SYMBOL as a variable.  Note that SYMBOL is not evaluated; the symbol to be defined should appear explicitly in the defvar form.  The variable is marked as special, meaning that it should always be dynamically bound (see Variable Scoping).

     If VALUE is specified, and SYMBOL is void (i.e., it has no dynamically bound value; see Void Variables), then VALUE is evaluated and SYMBOL is set to the result.  But if SYMBOL is not void, VALUE is not evaluated, and SYMBOL's value is left unchanged.  If VALUE is omitted, the value of SYMBOL is not changed in any case.

     Note that specifying a value, even nil, marks the variable as special permanently.  Whereas if VALUE is omitted then the variable is only marked special locally (i.e. within the current lexical scope, or file if at the top-level).  This can be useful for suppressing byte compilation warnings, see Compiler Errors.

     If SYMBOL has a buffer-local binding in the current buffer, defvar acts on the default value, which is buffer-independent, rather than the buffer-local binding.  It sets the default value if the default value is void.  See Buffer-Local Variables.

     If SYMBOL is already let bound (e.g., if the defvar form occurs in a let form), then defvar sets the toplevel default value, like set-default-toplevel-value. The let binding remains in effect until its binding construct exits. See Variable Scoping.

     When you evaluate a top-level defvar form with C-M-x (eval-defun) or with C-x C-e (eval-last-sexp) in Emacs Lisp mode, a special feature of these two commands arranges to set the variable unconditionally, without testing whether its value is void.

     If the DOC-STRING argument is supplied, it specifies the documentation string for the variable (stored in the symbol's variable-documentation property).  See Documentation.

     Here are some examples.  This form defines foo but does not initialize it:

          (defvar foo)
               => foo

     This example initializes the value of bar to 23, and gives it a documentation string:

          (defvar bar 23
            "The normal weight of a bar.")
               => bar

     The defvar form returns SYMBOL, but it is normally used at top level in a file where its value does not matter.

     For a more elaborate example of using defvar without a value, see Local defvar example.

 -- Special Form: defconst symbol value [doc-string]
     This special form defines SYMBOL as a value and initializes it. It informs a person reading your code that SYMBOL has a standard global value, established here, that should not be changed by the user or by other programs.  Note that SYMBOL is not evaluated; the symbol to be defined must appear explicitly in the defconst.

     The defconst form, like defvar, marks the variable as special, meaning that it should always be dynamically bound (see Variable Scoping).  In addition, it marks the variable as risky (see File Local Variables).

     defconst always evaluates VALUE, and sets the value of SYMBOL to the result.  If SYMBOL does have a buffer-local binding in the current buffer, defconst sets the default value, not the buffer-local value.  (But you should not be making buffer-local bindings for a symbol that is defined with defconst.)

     An example of the use of defconst is Emacs's definition of float-pi---the mathematical constant pi, which ought not to be changed by anyone (attempts by the Indiana State Legislature notwithstanding).  As the second form illustrates, however, defconst is only advisory.

          (defconst float-pi 3.141592653589793 "The value of Pi.")
               => float-pi

          (setq float-pi 3)
               => float-pi

          float-pi
               => 3

Warning: If you use a defconst or defvar special form while the variable has a local binding (made with let, or a function argument), it sets the local binding rather than the global binding.  This is not what you usually want.  To prevent this, use these special forms at top level in a file, where normally no local binding is in effect, and make sure to load the file before making a local binding for the variable.

Tips for Defining Variables Robustly
====================================

When you define a variable whose value is a function, or a list of functions, use a name that ends in -function or -functions, respectively.

There are several other variable name conventions; here is a complete list:

...-hook
     The variable is a normal hook (see Hooks).

...-function
     The value is a function.

...-functions
     The value is a list of functions.

...-form
     The value is a form (an expression).

...-forms
     The value is a list of forms (expressions).

...-predicate
     The value is a predicate---a function of one argument that returns non-nil for success and nil for failure.

...-flag
     The value is significant only as to whether it is nil or not. Since such variables often end up acquiring more values over time, this convention is not strongly recommended.

...-program
     The value is a program name.

...-command
     The value is a whole shell command.

...-switches
     The value specifies options for a command.

PREFIX--...
     The variable is intended for internal use and is defined in the file PREFIX.el.  (Emacs code contributed before 2018 may follow other conventions, which are being phased out.)

...-internal
     The variable is intended for internal use and is defined in C code. (Emacs code contributed before 2018 may follow other conventions, which are being phased out.)

When you define a variable, always consider whether you should mark it as safe or risky; see File Local Variables.

When defining and initializing a variable that holds a complicated value (such as a keymap with bindings in it), it's best to put the entire computation of the value into the defvar, like this:

     (defvar my-mode-map
       (let ((map (make-sparse-keymap)))
         (keymap-set map "C-c C-a" 'my-command)
         ...
         map)
       DOCSTRING)

This method has several benefits.  First, if the user quits while loading the file, the variable is either still uninitialized or initialized properly, never in-between.  If it is still uninitialized, reloading the file will initialize it properly.  Second, reloading the file once the variable is initialized will not alter it; that is important if the user has run hooks to alter part of the contents (such as, to rebind keys).  Third, evaluating the defvar form with C-M-x will reinitialize the map completely.

Accessing Variable Values
=========================

The usual way to reference a variable is to write the symbol which names it.  See Symbol Forms.

Occasionally, you may want to reference a variable which is only determined at run time.  In that case, you cannot specify the variable name in the text of the program.  You can use the symbol-value function to extract the value.

 -- Function: symbol-value symbol
     This function returns the value stored in SYMBOL's value cell. This is where the variable's current (dynamic) value is stored.  If the variable has no local binding, this is simply its global value. If the variable is void, a void-variable error is signaled.

     If the variable is lexically bound, the value reported by symbol-value is not necessarily the same as the variable's lexical value, which is determined by the lexical environment rather than the symbol's value cell.  See Variable Scoping.

          (setq abracadabra 5)
               => 5

          (setq foo 9)
               => 9

          ;; Here the symbol abracadabra
          ;;   is the symbol whose value is examined.
          (let ((abracadabra 'foo))
            (symbol-value 'abracadabra))
               => foo

          ;; Here, the value of abracadabra,
          ;;   which is foo,
          ;;   is the symbol whose value is examined.
          (let ((abracadabra 'foo))
            (symbol-value abracadabra))
               => 9

          (symbol-value 'abracadabra)
               => 5

Setting Variable Values
=======================

The usual way to change the value of a variable is with the special form setq.  When you need to compute the choice of variable at run time, use the function set.

 -- Special Form: setq [symbol form]...
     This special form is the most common method of changing a variable's value.  Each SYMBOL is given a new value, which is the result of evaluating the corresponding FORM.  The current binding of the symbol is changed.

     setq does not evaluate SYMBOL; it sets the symbol that you write.  We say that this argument is automatically quoted.  The q in setq stands for ``quoted''.

     The value of the setq form is the value of the last FORM.

          (setq x (1+ 2))
               => 3

          x                   ; x now has a global value.
               => 3

          (let ((x 5))
            (setq x 6)        ; The local binding of x is set.
            x)
               => 6

          x                   ; The global value is unchanged.
               => 3

     Note that the first FORM is evaluated, then the first SYMBOL is set, then the second FORM is evaluated, then the second SYMBOL is set, and so on:

          (setq x 10          ; Notice that x is set before
                y (1+ x))     ;   the value of y is computed.
               => 11

 -- Function: set symbol value
     This function puts VALUE in the value cell of SYMBOL. Since it is a function rather than a special form, the expression written for SYMBOL is evaluated to obtain the symbol to set. The return value is VALUE.

     When dynamic variable binding is in effect (the default), set has the same effect as setq, apart from the fact that set evaluates its SYMBOL argument whereas setq does not.  But when a variable is lexically bound, set affects its dynamic value, whereas setq affects its current (lexical) value.  See Variable Scoping.

          (set one 1)
          error--> Symbol's value as variable is void: one

          (set 'one 1)
               => 1

          (set 'two 'one)
               => one

          (set two 2)         ; two evaluates to symbol one.
               => 2

          one                 ; So it is one that was set.
               => 2
          (let ((one 1))      ; This binding of one is set,
            (set 'one 3)      ;   not the global value.
            one)
               => 3

          one
               => 2

     If SYMBOL is not actually a symbol, a wrong-type-argument error is signaled.

          (set '(x y) 'z)
          error--> Wrong type argument: symbolp, (x y)

 -- Macro: setopt [symbol form]...
     This is like setq (see above), but meant for user options. This macro uses the Customize machinery to set the variable(s).  In particular, setopt will run the setter function associated with the variable.  For instance, if you have:

          (defcustom my-var 1
            "My var."
            :type 'number
            :set (lambda (var val)
                   (set-default var val)
                   (message "We set %s to %s" var val)))

     then the following, in addition to setting my-var to 2, will also issue a message:

          (setopt my-var 2)

     setopt also checks whether the value is valid for the user option.  For instance, using setopt to set a user option defined with a number type to a string will signal an error.

     The setopt macro can be used on regular, non-user option variables, but is much less efficient than setq.  The main use case for this macro is setting user options in the user's init file.

Running a function when a variable is changed.
==============================================

It is sometimes useful to take some action when a variable changes its value.  The variable watchpoint facility provides the means to do so.  Some possible uses for this feature include keeping display in sync with variable settings, and invoking the debugger to track down unexpected changes to variables (see Variable Debugging).

The following functions may be used to manipulate and query the watch functions for a variable.

 -- Function: add-variable-watcher symbol watch-function
     This function arranges for WATCH-FUNCTION to be called whenever SYMBOL is modified.  Modifications through aliases (see Variable Aliases) will have the same effect.

     WATCH-FUNCTION will be called, just before changing the value of SYMBOL, with 4 arguments: SYMBOL, NEWVAL, OPERATION, and WHERE. SYMBOL is the variable being changed.  NEWVAL is the value it will be changed to.  (The old value is available to WATCH-FUNCTION as the value of SYMBOL, since it was not yet changed to NEWVAL.)  OPERATION is a symbol representing the kind of change, one of: set, let, unlet, makunbound, or defvaralias.  WHERE is a buffer if the buffer-local value of the variable is being changed, nil otherwise.

 -- Function: remove-variable-watcher symbol watch-function
     This function removes WATCH-FUNCTION from SYMBOL's list of watchers.

 -- Function: get-variable-watchers symbol
     This function returns the list of SYMBOL's active watcher functions.

Limitations
-----------

There are a couple of ways in which a variable could be modified (or at least appear to be modified) without triggering a watchpoint.

Since watchpoints are attached to symbols, modification to the objects contained within variables (e.g., by a list modification function see Modifying Lists) is not caught by this mechanism.

Additionally, C code can modify the value of variables directly, bypassing the watchpoint mechanism.

A minor limitation of this feature, again because it targets symbols, is that only variables of dynamic scope may be watched.  This poses little difficulty, since modifications to lexical variables can be discovered easily by inspecting the code within the scope of the variable (unlike dynamic variables, which can be modified by any code at all, see Variable Scoping).

Scoping Rules for Variable Bindings
===================================

When you create a local binding for a variable, that binding takes effect only within a limited portion of the program (see Local Variables).  This section describes exactly what this means.

Each local binding has a certain scope and extent. Scope refers to where in the textual source code the binding can be accessed.  Extent refers to when, as the program is executing, the binding exists.

By default, the local bindings that Emacs creates are dynamic bindings.  Such a binding has dynamic scope, meaning that any part of the program can potentially access the variable binding.  It also has dynamic extent, meaning that the binding lasts only while the binding construct (such as the body of a let form) is being executed.

Emacs can optionally create lexical bindings.  A lexical binding has lexical scope, meaning that any reference to the variable must be located textually within the binding construct (With some exceptions; for instance, a lexical binding can also be accessed from the Lisp debugger.).  It also has indefinite extent, meaning that under some circumstances the binding can live on even after the binding construct has finished executing, by means of special objects called closures.

The following subsections describe dynamic binding and lexical binding in greater detail, and how to enable lexical binding in Emacs Lisp programs.

Dynamic Binding
---------------

By default, the local variable bindings made by Emacs are dynamic bindings.  When a variable is dynamically bound, its current binding at any point in the execution of the Lisp program is simply the most recently-created dynamic local binding for that symbol, or the global binding if there is no such local binding.

Dynamic bindings have dynamic scope and extent, as shown by the following example:

     (defvar x -99)  ; x receives an initial value of -99.

     (defun getx ()
       x)            ; x is used free in this function.

     (let ((x 1))    ; x is dynamically bound.
       (getx))
          => 1

     ;; After the let form finishes, x reverts to its
     ;; previous value, which is -99.

     (getx)
          => -99

The function getx refers to x.  This is a free reference, in the sense that there is no binding for x within that defun construct itself.  When we call getx from within a let form in which x is (dynamically) bound, it retrieves the local value (i.e., 1).  But when we call getx outside the let form, it retrieves the global value (i.e., -99).

Here is another example, which illustrates setting a dynamically bound variable using setq:

     (defvar x -99)      ; x receives an initial value of -99.

     (defun addx ()
       (setq x (1+ x)))  ; Add 1 to x and return its new value.

     (let ((x 1))
       (addx)
       (addx))
          => 3           ; The two addx calls add to x twice.

     ;; After the let form finishes, x reverts to its
     ;; previous value, which is -99.

     (addx)
          => -98

Dynamic binding is implemented in Emacs Lisp in a simple way.  Each symbol has a value cell, which specifies its current dynamic value (or absence of value).  See Symbol Components.  When a symbol is given a dynamic local binding, Emacs records the contents of the value cell (or absence thereof) in a stack, and stores the new local value in the value cell.  When the binding construct finishes executing, Emacs pops the old value off the stack, and puts it in the value cell.

Note that when code using Dynamic Binding is native compiled the native compiler will not perform any Lisp specific optimization.

Proper Use of Dynamic Binding
-----------------------------

Dynamic binding is a powerful feature, as it allows programs to refer to variables that are not defined within their local textual scope.  However, if used without restraint, this can also make programs hard to understand.  There are two clean ways to use this technique:

  * If a variable has no global definition, use it as a local variable only within a binding construct, such as the body of the let form where the variable was bound.  If this convention is followed consistently throughout a program, the value of the variable will not affect, nor be affected by, any uses of the same variable symbol elsewhere in the program.

  * Otherwise, define the variable with defvar, defconst (see Defining Variables), or defcustom (see Variable Definitions).  Usually, the definition should be at top-level in an Emacs Lisp file.  As far as possible, it should include a documentation string which explains the meaning and purpose of the variable.  You should also choose the variable's name to avoid name conflicts (see Coding Conventions).

     Then you can bind the variable anywhere in a program, knowing reliably what the effect will be.  Wherever you encounter the variable, it will be easy to refer back to the definition, e.g., via the C-h v command (provided the variable definition has been loaded into Emacs). See Name Help (The GNU Emacs Manual).

     For example, it is common to use local bindings for customizable variables like case-fold-search:

          (defun search-for-abc ()
            "Search for the string \"abc\", ignoring case differences."
            (let ((case-fold-search t))
              (re-search-forward "abc")))

Lexical Binding
---------------

Lexical binding was introduced to Emacs, as an optional feature, in version 24.1.  We expect its importance to increase with time. Lexical binding opens up many more opportunities for optimization, so programs using it are likely to run faster in future Emacs versions. Lexical binding is also more compatible with concurrency, which was added to Emacs in version 26.1.

A lexically-bound variable has lexical scope, meaning that any reference to the variable must be located textually within the binding construct.  Here is an example (see Using Lexical Binding, for how to actually enable lexical binding):

     (let ((x 1))    ; x is lexically bound.
       (+ x 3))
          => 4

     (defun getx ()
       x)            ; x is used free in this function.

     (let ((x 1))    ; x is lexically bound.
       (getx))
     error--> Symbol's value as variable is void: x

Here, the variable x has no global value.  When it is lexically bound within a let form, it can be used in the textual confines of that let form.  But it can not be used from within a getx function called from the let form, since the function definition of getx occurs outside the let form itself.

Here is how lexical binding works.  Each binding construct defines a lexical environment, specifying the variables that are bound within the construct and their local values.  When the Lisp evaluator wants the current value of a variable, it looks first in the lexical environment; if the variable is not specified in there, it looks in the symbol's value cell, where the dynamic value is stored.

(Internally, the lexical environment is an alist of symbol-value pairs, with the final element in the alist being the symbol t rather than a cons cell.  Such an alist can be passed as the second argument to the eval function, in order to specify a lexical environment in which to evaluate a form.  See Eval.  Most Emacs Lisp programs, however, should not interact directly with lexical environments in this way; only specialized programs like debuggers.)

Lexical bindings have indefinite extent.  Even after a binding construct has finished executing, its lexical environment can be ``kept around'' in Lisp objects called closures.  A closure is created when you define a named or anonymous function with lexical binding enabled.  See Closures, for details.

When a closure is called as a function, any lexical variable references within its definition use the retained lexical environment. Here is an example:

     (defvar my-ticker nil)   ; We will use this dynamically bound
                              ; variable to store a closure.

     (let ((x 0))             ; x is lexically bound.
       (setq my-ticker (lambda ()
                         (setq x (1+ x)))))
         => (closure ((x . 0) t) ()
               (setq x (1+ x)))

     (funcall my-ticker)
         => 1

     (funcall my-ticker)
         => 2

     (funcall my-ticker)
         => 3

     x                        ; Note that x has no global value.
     error--> Symbol's value as variable is void: x

The let binding defines a lexical environment in which the variable x is locally bound to 0.  Within this binding construct, we define a lambda expression which increments x by one and returns the incremented value.  This lambda expression is automatically turned into a closure, in which the lexical environment lives on even after the let binding construct has exited.  Each time we evaluate the closure, it increments x, using the binding of x in that lexical environment.

Note that unlike dynamic variables which are tied to the symbol object itself, the relationship between lexical variables and symbols is only present in the interpreter (or compiler).  Therefore, functions which take a symbol argument (like symbol-value, boundp, and set) can only retrieve or modify a variable's dynamic binding (i.e., the contents of its symbol's value cell).

Using Lexical Binding
---------------------

When loading an Emacs Lisp file or evaluating a Lisp buffer, lexical binding is enabled if the buffer-local variable lexical-binding is non-nil:

 -- Variable: lexical-binding
     If this buffer-local variable is non-nil, Emacs Lisp files and buffers are evaluated using lexical binding instead of dynamic binding.  (However, special variables are still dynamically bound; see below.)  If nil, dynamic binding is used for all local variables.  This variable is typically set for a whole Emacs Lisp file, as a file local variable (see File Local Variables). Note that unlike other such variables, this one must be set in the first line of a file.

When evaluating Emacs Lisp code directly using an eval call, lexical binding is enabled if the LEXICAL argument to eval is non-nil.  See Eval.

Lexical binding is also enabled in Lisp Interaction and IELM mode, used in the *scratch* and *ielm* buffers, and also when evaluating expressions via M-: (eval-expression) and when processing the --eval command-line options of Emacs (see Action Arguments (The GNU Emacs Manual)) and emacsclient (see emacsclient Options (The GNU Emacs Manual)).

Even when lexical binding is enabled, certain variables will continue to be dynamically bound.  These are called special variables.  Every variable that has been defined with defvar, defcustom or defconst is a special variable (see Defining Variables).  All other variables are subject to lexical binding.

Using defvar without a value, it is possible to bind a variable dynamically just in one file, or in just one part of a file while still binding it lexically elsewhere.  For example:

     (let (_)
       (defvar x)      ; Let-bindings of x will be dynamic within this let.
       (let ((x -99))  ; This is a dynamic binding of x.
         (defun get-dynamic-x ()
           x)))

     (let ((x 'lexical)) ; This is a lexical binding of x.
       (defun get-lexical-x ()
         x))

     (let (_)
       (defvar x)
       (let ((x 'dynamic))
         (list (get-lexical-x)
               (get-dynamic-x))))
         => (lexical dynamic)

 -- Function: special-variable-p symbol
     This function returns non-nil if SYMBOL is a special variable (i.e., it has a defvar, defcustom, or defconst variable definition).  Otherwise, the return value is nil.

     Note that since this is a function, it can only return non-nil for variables which are permanently special, but not for those that are only special in the current lexical scope.

The use of a special variable as a formal argument in a function is not supported.

Converting to Lexical Binding
-----------------------------

Converting an Emacs Lisp program to lexical binding is easy.  First, add a file-local variable setting of lexical-binding to t in the header line of the Emacs Lisp source file (see File Local Variables).  Second, check that every variable in the program which needs to be dynamically bound has a variable definition, so that it is not inadvertently bound lexically.

A simple way to find out which variables need a variable definition is to byte-compile the source file.  See Byte Compilation.  If a non-special variable is used outside of a let form, the byte-compiler will warn about reference or assignment to a free variable.  If a non-special variable is bound but not used within a let form, the byte-compiler will warn about an unused lexical variable.  The byte-compiler will also issue a warning if you use a special variable as a function argument.

A warning about a reference or an assignment to a free variable is usually a clear sign that that variable should be marked as dynamically scoped, so you need to add an appropriate defvar before the first use of that variable.

A warning about an unused variable may be a good hint that the variable was intended to be dynamically scoped (because it is actually used, but in another function), but it may also be an indication that the variable is simply really not used and could simply be removed. So you need to find out which case it is, and based on that, either add a defvar or remove the variable altogether.  If removal is not possible or not desirable (typically because it is a formal argument and that we cannot or don't want to change all the callers), you can also add a leading underscore to the variable's name to indicate to the compiler that this is a variable known not to be used.)

Cross-file variable checking
............................

Caution: This is an experimental feature that may change or disappear without prior notice.

The byte-compiler can also warn about lexical variables that are special in other Emacs Lisp files, often indicating a missing defvar declaration.  This useful but somewhat specialized check requires three steps:

 1. Byte-compile all files whose special variable declarations may be of interest, with the environment variable EMACS_GENERATE_DYNVARS set to a nonempty string.  These are typically all the files in the same package or related packages or Emacs subsystems.  The process will generate a file whose name ends in .dynvars for each compiled Emacs Lisp file.

 2. Concatenate the .dynvars files into a single file.

 3. Byte-compile the files that need to be checked, this time with the environment variable EMACS_DYNVARS_FILE set to the name of the aggregated file created in step 2.

Here is an example illustrating how this could be done, assuming that a Unix shell and make are used for byte-compilation:

     $ rm *.elc                                # force recompilation
     $ EMACS_GENERATE_DYNVARS=1 make           # generate .dynvars
     $ cat *.dynvars > ~/my-dynvars            # combine .dynvars
     $ rm *.elc                                # force recompilation
     $ EMACS_DYNVARS_FILE=~/my-dynvars make    # perform checks

Buffer-Local Variables
======================

Global and local variable bindings are found in most programming languages in one form or another.  Emacs, however, also supports additional, unusual kinds of variable binding, such as buffer-local bindings, which apply only in one buffer.  Having different values for a variable in different buffers is an important customization method.  (Variables can also have bindings that are local to each terminal.  See Multiple Terminals.)

Introduction to Buffer-Local Variables
--------------------------------------

A buffer-local variable has a buffer-local binding associated with a particular buffer.  The binding is in effect when that buffer is current; otherwise, it is not in effect.  If you set the variable while a buffer-local binding is in effect, the new value goes in that binding, so its other bindings are unchanged.  This means that the change is visible only in the buffer where you made it.

The variable's ordinary binding, which is not associated with any specific buffer, is called the default binding.  In most cases, this is the global binding.

A variable can have buffer-local bindings in some buffers but not in other buffers.  The default binding is shared by all the buffers that don't have their own bindings for the variable.  (This includes all newly-created buffers.)  If you set the variable in a buffer that does not have a buffer-local binding for it, this sets the default binding, so the new value is visible in all the buffers that see the default binding.

The most common use of buffer-local bindings is for major modes to change variables that control the behavior of commands.  For example, C mode and Lisp mode both set the variable paragraph-start to specify that only blank lines separate paragraphs.  They do this by making the variable buffer-local in the buffer that is being put into C mode or Lisp mode, and then setting it to the new value for that mode.  See Major Modes.

The usual way to make a buffer-local binding is with make-local-variable, which is what major mode commands typically use.  This affects just the current buffer; all other buffers (including those yet to be created) will continue to share the default value unless they are explicitly given their own buffer-local bindings.

A more powerful operation is to mark the variable as automatically buffer-local by calling make-variable-buffer-local.  You can think of this as making the variable local in all buffers, even those yet to be created.  More precisely, the effect is that setting the variable automatically makes the variable local to the current buffer if it is not already so.  All buffers start out by sharing the default value of the variable as usual, but setting the variable creates a buffer-local binding for the current buffer.  The new value is stored in the buffer-local binding, leaving the default binding untouched.  This means that the default value cannot be changed with setq in any buffer; the only way to change it is with setq-default.

Warning: When a variable has buffer-local bindings in one or more buffers, let rebinds the binding that's currently in effect.  For instance, if the current buffer has a buffer-local value, let temporarily rebinds that.  If no buffer-local bindings are in effect, let rebinds the default value.  If inside the let you then change to a different current buffer in which a different binding is in effect, you won't see the let binding any more.  And if you exit the let while still in the other buffer, you won't see the unbinding occur (though it will occur properly).  Here is an example to illustrate:

     (setq foo 'g)
     (set-buffer "a")
     (make-local-variable 'foo)

     (setq foo 'a)
     (let ((foo 'temp))
       ;; foo => 'temp  ; let binding in buffer a
       (set-buffer "b")
       ;; foo => 'g     ; the global value since foo is not local in b
       BODY...)

     foo => 'g        ; exiting restored the local value in buffer a,
                      ; but we don't see that in buffer b

     (set-buffer "a") ; verify the local value was restored
     foo => 'a

Note that references to foo in BODY access the buffer-local binding of buffer b.

When a file specifies local variable values, these become buffer-local values when you visit the file.  See File Variables (The GNU Emacs Manual).

A buffer-local variable cannot be made terminal-local (see Multiple Terminals).

Creating and Deleting Buffer-Local Bindings
-------------------------------------------

 -- Command: make-local-variable variable
     This function creates a buffer-local binding in the current buffer for VARIABLE (a symbol).  Other buffers are not affected.  The value returned is VARIABLE.

     The buffer-local value of VARIABLE starts out as the same value VARIABLE previously had.  If VARIABLE was void, it remains void.

          ;; In buffer b1:
          (setq foo 5)                ; Affects all buffers.
               => 5

          (make-local-variable 'foo)  ; Now it is local in b1.
               => foo

          foo                         ; That did not change
               => 5                   ;   the value.

          (setq foo 6)                ; Change the value
               => 6                   ;   in b1.

          foo
               => 6

          ;; In buffer b2, the value hasn't changed.
          (with-current-buffer "b2"
            foo)
               => 5

     Making a variable buffer-local within a let-binding for that variable does not work reliably, unless the buffer in which you do this is not current either on entry to or exit from the let.  This is because let does not distinguish between different kinds of bindings; it knows only which variable the binding was made for.

     It is an error to make a constant or a read-only variable buffer-local.  See Constant Variables.

     If the variable is terminal-local (see Multiple Terminals), this function signals an error.  Such variables cannot have buffer-local bindings as well.

     Warning: do not use make-local-variable for a hook variable.  The hook variables are automatically made buffer-local as needed if you use the LOCAL argument to add-hook or remove-hook.

 -- Macro: setq-local &rest pairs
     PAIRS is a list of variable and value pairs.  This macro creates a buffer-local binding in the current buffer for each of the variables, and gives them a buffer-local value.  It is equivalent to calling make-local-variable followed by setq for each of the variables.  The variables should be unquoted symbols.

          (setq-local var1 "value1"
                      var2 "value2")

 -- Command: make-variable-buffer-local variable
     This function marks VARIABLE (a symbol) automatically buffer-local, so that any subsequent attempt to set it will make it local to the current buffer at the time.  Unlike make-local-variable, with which it is often confused, this cannot be undone, and affects the behavior of the variable in all buffers.

     A peculiar wrinkle of this feature is that binding the variable (with let or other binding constructs) does not create a buffer-local binding for it.  Only setting the variable (with set or setq), while the variable does not have a let-style binding that was made in the current buffer, does so.

     If VARIABLE does not have a default value, then calling this command will give it a default value of nil.  If VARIABLE already has a default value, that value remains unchanged. Subsequently calling makunbound on VARIABLE will result in a void buffer-local value and leave the default value unaffected.

     The value returned is VARIABLE.

     It is an error to make a constant or a read-only variable buffer-local.  See Constant Variables.

     Warning: Don't assume that you should use make-variable-buffer-local for user-option variables, simply because users might want to customize them differently in different buffers.  Users can make any variable local, when they wish to.  It is better to leave the choice to them.

     The time to use make-variable-buffer-local is when it is crucial that no two buffers ever share the same binding.  For example, when a variable is used for internal purposes in a Lisp program which depends on having separate values in separate buffers, then using make-variable-buffer-local can be the best solution.

 -- Macro: defvar-local variable value &optional docstring
     This macro defines VARIABLE as a variable with initial value VALUE and DOCSTRING, and marks it as automatically buffer-local.  It is equivalent to calling defvar followed by make-variable-buffer-local.  VARIABLE should be an unquoted symbol.

 -- Function: local-variable-p variable &optional buffer
     This returns t if VARIABLE is buffer-local in buffer BUFFER (which defaults to the current buffer); otherwise, nil.

 -- Function: local-variable-if-set-p variable &optional buffer
     This returns t if VARIABLE either has a buffer-local value in buffer BUFFER, or is automatically buffer-local. Otherwise, it returns nil.  If omitted or nil, BUFFER defaults to the current buffer.

 -- Function: buffer-local-value variable buffer
     This function returns the buffer-local binding of VARIABLE (a symbol) in buffer BUFFER.  If VARIABLE does not have a buffer-local binding in buffer BUFFER, it returns the default value (see Default Value) of VARIABLE instead.

 -- Function: buffer-local-boundp variable buffer
     This returns non-nil if there's either a buffer-local binding of VARIABLE (a symbol) in buffer BUFFER, or VARIABLE has a global binding.

 -- Function: buffer-local-variables &optional buffer
     This function returns a list describing the buffer-local variables in buffer BUFFER.  (If BUFFER is omitted, the current buffer is used.)  Normally, each list element has the form (SYM . VAL), where SYM is a buffer-local variable (a symbol) and VAL is its buffer-local value.  But when a variable's buffer-local binding in BUFFER is void, its list element is just SYM.

          (make-local-variable 'foobar)
          (makunbound 'foobar)
          (make-local-variable 'bind-me)
          (setq bind-me 69)

          (setq lcl (buffer-local-variables))
              ;; First, built-in variables local in all buffers:
          => ((mark-active . nil)
              (buffer-undo-list . nil)
              (mode-name . "Fundamental")
              ...

              ;; Next, non-built-in buffer-local variables.
              ;; This one is buffer-local and void:
              foobar
              ;; This one is buffer-local and nonvoid:
              (bind-me . 69))

     Note that storing new values into the CDRs of cons cells in this list does not change the buffer-local values of the variables.

 -- Command: kill-local-variable variable
     This function deletes the buffer-local binding (if any) for VARIABLE (a symbol) in the current buffer.  As a result, the default binding of VARIABLE becomes visible in this buffer.  This typically results in a change in the value of VARIABLE, since the default value is usually different from the buffer-local value just eliminated.

     If you kill the buffer-local binding of a variable that automatically becomes buffer-local when set, this makes the default value visible in the current buffer.  However, if you set the variable again, that will once again create a buffer-local binding for it.

     kill-local-variable returns VARIABLE.

     This function is a command because it is sometimes useful to kill one buffer-local variable interactively, just as it is useful to create buffer-local variables interactively.

 -- Function: kill-all-local-variables &optional kill-permanent
     This function eliminates all the buffer-local variable bindings of the current buffer.  As a result, the buffer will see the default values of most variables.  By default, for variables marked as permanent and local hook functions that have a non-nil permanent-local-hook property (see Setting Hooks) won't be killed, but if the optional KILL-PERMANENT argument is non-nil, even these variables will be killed.

     This function also resets certain other information pertaining to the buffer: it sets the local keymap to nil, the syntax table to the value of (standard-syntax-table), the case table to (standard-case-table), and the abbrev table to the value of fundamental-mode-abbrev-table.

     The very first thing this function does is run the normal hook change-major-mode-hook (see below).

     Every major mode command begins by calling this function, which has the effect of switching to Fundamental mode and erasing most of the effects of the previous major mode.  To ensure that this does its job, the variables that major modes set should not be marked permanent.

     kill-all-local-variables returns nil.

 -- Variable: change-major-mode-hook
     The function kill-all-local-variables runs this normal hook before it does anything else.  This gives major modes a way to arrange for something special to be done if the user switches to a different major mode.  It is also useful for buffer-specific minor modes that should be forgotten if the user changes the major mode.

     For best results, make this variable buffer-local, so that it will disappear after doing its job and will not interfere with the subsequent major mode.  See Hooks.

A buffer-local variable is permanent if the variable name (a symbol) has a permanent-local property that is non-nil. Such variables are unaffected by kill-all-local-variables, and their local bindings are therefore not cleared by changing major modes. Permanent locals are appropriate for data pertaining to where the file came from or how to save it, rather than with how to edit the contents.

The Default Value of a Buffer-Local Variable
--------------------------------------------

The global value of a variable with buffer-local bindings is also called the default value, because it is the value that is in effect whenever neither the current buffer nor the selected frame has its own binding for the variable.

The functions default-value and setq-default access and change a variable's default value regardless of whether the current buffer has a buffer-local binding.  For example, you could use setq-default to change the default setting of paragraph-start for most buffers; and this would work even when you are in a C or Lisp mode buffer that has a buffer-local value for this variable.

The special forms defvar and defconst also set the default value (if they set the variable at all), rather than any buffer-local value.

 -- Function: default-value symbol
     This function returns SYMBOL's default value.  This is the value that is seen in buffers and frames that do not have their own values for this variable.  If SYMBOL is not buffer-local, this is equivalent to symbol-value (see Accessing Variables).

 -- Function: default-boundp symbol
     The function default-boundp tells you whether SYMBOL's default value is nonvoid.  If (default-boundp 'foo) returns nil, then (default-value 'foo) would get an error.

     default-boundp is to default-value as boundp is to symbol-value.

 -- Special Form: setq-default [symbol form]...
     This special form gives each SYMBOL a new default value, which is the result of evaluating the corresponding FORM.  It does not evaluate SYMBOL, but does evaluate FORM.  The value of the setq-default form is the value of the last FORM.

     If a SYMBOL is not buffer-local for the current buffer, and is not marked automatically buffer-local, setq-default has the same effect as setq.  If SYMBOL is buffer-local for the current buffer, then this changes the value that other buffers will see (as long as they don't have a buffer-local value), but not the value that the current buffer sees.

          ;; In buffer foo:
          (make-local-variable 'buffer-local)
               => buffer-local

          (setq buffer-local 'value-in-foo)
               => value-in-foo

          (setq-default buffer-local 'new-default)
               => new-default

          buffer-local
               => value-in-foo

          (default-value 'buffer-local)
               => new-default

          ;; In (the new) buffer bar:
          buffer-local
               => new-default

          (default-value 'buffer-local)
               => new-default

          (setq buffer-local 'another-default)
               => another-default

          (default-value 'buffer-local)
               => another-default

          ;; Back in buffer foo:
          buffer-local
               => value-in-foo
          (default-value 'buffer-local)
               => another-default

 -- Function: set-default symbol value
     This function is like setq-default, except that SYMBOL is an ordinary evaluated argument.

          (set-default (car '(a b c)) 23)
               => 23

          (default-value 'a)
               => 23

A variable can be let-bound (see Local Variables) to a value. This makes its global value shadowed by the binding; default-value will then return the value from that binding, not the global value, and set-default will be prevented from setting the global value (it will change the let-bound value instead). The following two functions allow to reference the global value even if it's shadowed by a let-binding.

 -- Function: default-toplevel-value symbol
     This function returns the top-level default value of SYMBOL, which is its value outside of any let-binding.

     (defvar variable 'global-value)
         => variable

     (let ((variable 'let-binding))
       (default-value 'variable))
         => let-binding

     (let ((variable 'let-binding))
       (default-toplevel-value 'variable))
         => global-value

 -- Function: set-default-toplevel-value symbol value
     This function sets the top-level default value of SYMBOL to the specified VALUE.  This comes in handy when you want to set the global value of SYMBOL regardless of whether your code runs in the context of SYMBOL's let-binding.

File Local Variables
====================

A file can specify local variable values; Emacs uses these to create buffer-local bindings for those variables in the buffer visiting that file.  See Local Variables in Files (The GNU Emacs Manual), for basic information about file-local variables. This section describes the functions and variables that affect how file-local variables are processed.

If a file-local variable could specify an arbitrary function or Lisp expression that would be called later, visiting a file could take over your Emacs.  Emacs protects against this by automatically setting only those file-local variables whose specified values are known to be safe.  Other file-local variables are set only if the user agrees.

For additional safety, read-circle is temporarily bound to nil when Emacs reads file-local variables (see Input Functions).  This prevents the Lisp reader from recognizing circular and shared Lisp structures (see Circular Objects).

 -- User Option: enable-local-variables
     This variable controls whether to process file-local variables. The possible values are:

     t (the default)
          Set the safe variables, and query (once) about any unsafe variables.

     :safe
          Set only the safe variables and do not query.

     :all
          Set all the variables and do not query.

     nil
          Don't set any variables.

     anything else
          Query (once) about all the variables.

 -- Variable: inhibit-local-variables-regexps
     This is a list of regular expressions.  If a file has a name matching an element of this list, then it is not scanned for any form of file-local variable.  For examples of why you might want to use this, see Auto Major Mode.

 -- Variable: permanently-enabled-local-variables
     Some local variable settings will, by default, be heeded even if enable-local-variables is nil.  By default, this is only the case for the lexical-binding local variable setting, but this can be controlled by using this variable, which is a list of symbols.

 -- Function: hack-local-variables &optional handle-mode
     This function parses, and binds or evaluates as appropriate, any local variables specified by the contents of the current buffer.  The variable enable-local-variables has its effect here.  However, this function does not look for the mode: local variable in the -*- line.  set-auto-mode does that, also taking enable-local-variables into account (see Auto Major Mode).

     This function works by walking the alist stored in file-local-variables-alist and applying each local variable in turn.  It calls before-hack-local-variables-hook and hack-local-variables-hook before and after applying the variables, respectively.  It only calls the before-hook if the alist is non-nil; it always calls the other hook.  This function ignores a mode element if it specifies the same major mode as the buffer already has.

     If the optional argument HANDLE-MODE is t, then all this function does is return a symbol specifying the major mode, if the -*- line or the local variables list specifies one, and nil otherwise.  It does not set the mode or any other file-local variable.  If HANDLE-MODE has any value other than nil or t, any settings of mode in the -*- line or the local variables list are ignored, and the other settings are applied.  If HANDLE-MODE is nil, all the file local variables are set.

 -- Variable: file-local-variables-alist
     This buffer-local variable holds the alist of file-local variable settings.  Each element of the alist is of the form (VAR . VALUE), where VAR is a symbol of the local variable and VALUE is its value.  When Emacs visits a file, it first collects all the file-local variables into this alist, and then the hack-local-variables function applies them one by one.

 -- Variable: before-hack-local-variables-hook
     Emacs calls this hook immediately before applying file-local variables stored in file-local-variables-alist.

 -- Variable: hack-local-variables-hook
     Emacs calls this hook immediately after it finishes applying file-local variables stored in file-local-variables-alist.

You can specify safe values for a variable with a safe-local-variable property.  The property has to be a function of one argument; any value is safe if the function returns non-nil given that value.  Many commonly-encountered file variables have safe-local-variable properties; these include fill-column, fill-prefix, and indent-tabs-mode. For boolean-valued variables that are safe, use booleanp as the property value.

If you want to define safe-local-variable properties for variables defined in C source code, add the names and the properties of those variables to the list in the ``Safe local variables'' section of files.el.

When defining a user option using defcustom, you can set its safe-local-variable property by adding the arguments :safe FUNCTION to defcustom (see Variable Definitions).  However, a safety predicate defined using :safe will only be known once the package that contains the defcustom is loaded, which is often too late.  As an alternative, you can use the autoload cookie (see Autoload) to assign the option its safety predicate, like this:

     ;;;###autoload (put 'VAR 'safe-local-variable 'PRED)

The safe value definitions specified with autoload are copied into the package's autoloads file (loaddefs.el for most packages bundled with Emacs), and are known to Emacs since the beginning of a session.

 -- User Option: safe-local-variable-values
     This variable provides another way to mark some variable values as safe.  It is a list of cons cells (VAR . VAL), where VAR is a variable name and VAL is a value which is safe for that variable.

     When Emacs asks the user whether or not to obey a set of file-local variable specifications, the user can choose to mark them as safe. Doing so adds those variable/value pairs to safe-local-variable-values, and saves it to the user's custom file.

 -- User Option: ignored-local-variable-values
     If there are some values of particular local variables that you always want to ignore completely, you can use this variable.  Its value has the same form as safe-local-variable-values; a file-local variable setting to the value that appears in the list will always be ignored when processing the local variables specified by the file.  As with that variable, when Emacs queries the user about whether to obey file-local variables, the user can choose to ignore their particular values permanently, and that will alter this variable and save it to the user's custom file.  Variable-value pairs that appear in this variable take precedence over the same pairs in safe-local-variable-values.

 -- Function: safe-local-variable-p sym val
     This function returns non-nil if it is safe to give SYM the value VAL, based on the above criteria.

Some variables are considered risky.  If a variable is risky, it is never entered automatically into safe-local-variable-values; Emacs always queries before setting a risky variable, unless the user explicitly allows a value by customizing safe-local-variable-values directly.

Any variable whose name has a non-nil risky-local-variable property is considered risky.  When you define a user option using defcustom, you can set its risky-local-variable property by adding the arguments :risky VALUE to defcustom (see Variable Definitions).  In addition, any variable whose name ends in any of -command, -frame-alist, -function, -functions, -hook, -hooks, -form, -forms, -map, -map-alist, -mode-alist, -program, or -predicate is automatically considered risky.  The variables font-lock-keywords, font-lock-keywords followed by a digit, and font-lock-syntactic-keywords are also considered risky.

 -- Function: risky-local-variable-p sym
     This function returns non-nil if SYM is a risky variable, based on the above criteria.

 -- Variable: ignored-local-variables
     This variable holds a list of variables that should not be given local values by files.  Any value specified for one of these variables is completely ignored.

The Eval: ``variable'' is also a potential loophole, so Emacs normally asks for confirmation before handling it.

 -- User Option: enable-local-eval
     This variable controls processing of Eval: in -*- lines or local variables lists in files being visited.  A value of t means process them unconditionally; nil means ignore them; anything else means ask the user what to do for each file.  The default value is maybe.

 -- User Option: safe-local-eval-forms
     This variable holds a list of expressions that are safe to evaluate when found in the Eval: ``variable'' in a file local variables list.

If the expression is a function call and the function has a safe-local-eval-function property, the property value determines whether the expression is safe to evaluate.  The property value can be a predicate to call to test the expression, a list of such predicates (it's safe if any predicate succeeds), or t (always safe provided the arguments are constant).

Text properties are also potential loopholes, since their values could include functions to call.  So Emacs discards all text properties from string values specified for file-local variables.

Directory Local Variables
=========================

A directory can specify local variable values common to all files in that directory; Emacs uses these to create buffer-local bindings for those variables in buffers visiting any file in that directory.  This is useful when the files in the directory belong to some project and therefore share the same local variables.

There are two different methods for specifying directory local variables: by putting them in a special file, or by defining a project class for that directory.

 -- Constant: dir-locals-file
     This constant is the name of the file where Emacs expects to find the directory-local variables.  The name of the file is .dir-locals.el (The MS-DOS version of Emacs uses _dir-locals.el instead, due to limitations of the DOS filesystems.).  A file by that name in a directory causes Emacs to apply its settings to any file in that directory or any of its subdirectories (optionally, you can exclude subdirectories; see below). If some of the subdirectories have their own .dir-locals.el files, Emacs uses the settings from the deepest file it finds starting from the file's directory and moving up the directory tree.  This constant is also used to derive the name of a second dir-locals file .dir-locals-2.el.  If this second dir-locals file is present, then that is loaded in addition to .dir-locals.el.  This is useful when .dir-locals.el is under version control in a shared repository and cannot be used for personal customizations.  The file specifies local variables as a specially formatted list; see Per-directory Local Variables (The GNU Emacs Manual), for more details.

 -- Function: hack-dir-local-variables
     This function reads the .dir-locals.el file and stores the directory-local variables in file-local-variables-alist that is local to the buffer visiting any file in the directory, without applying them.  It also stores the directory-local settings in dir-locals-class-alist, where it defines a special class for the directory in which .dir-locals.el file was found.  This function works by calling dir-locals-set-class-variables and dir-locals-set-directory-class, described below.

 -- Function: hack-dir-local-variables-non-file-buffer
     This function looks for directory-local variables, and immediately applies them in the current buffer.  It is intended to be called in the mode commands for non-file buffers, such as Dired buffers, to let them obey directory-local variable settings.  For non-file buffers, Emacs looks for directory-local variables in default-directory and its parent directories.

 -- Function: dir-locals-set-class-variables class variables
     This function defines a set of variable settings for the named CLASS, which is a symbol.  You can later assign the class to one or more directories, and Emacs will apply those variable settings to all files in those directories.  The list in VARIABLES can be of one of the two forms: (MAJOR-MODE . ALIST) or (DIRECTORY . LIST).  With the first form, if the file's buffer turns on a mode that is derived from MAJOR-MODE, then all the variables in the associated ALIST are applied; ALIST should be of the form (NAME . VALUE). A special value nil for MAJOR-MODE means the settings are applicable to any mode.  In ALIST, you can use a special NAME: subdirs.  If the associated value is nil, the alist is only applied to files in the relevant directory, not to those in any subdirectories.

     With the second form of VARIABLES, if DIRECTORY is the initial substring of the file's directory, then LIST is applied recursively by following the above rules; LIST should be of one of the two forms accepted by this function in VARIABLES.

 -- Function: dir-locals-set-directory-class directory class &optional mtime
     This function assigns CLASS to all the files in directory and its subdirectories.  Thereafter, all the variable settings specified for CLASS will be applied to any visited file in DIRECTORY and its children.  CLASS must have been already defined by dir-locals-set-class-variables.

     Emacs uses this function internally when it loads directory variables from a .dir-locals.el file.  In that case, the optional argument MTIME holds the file modification time (as returned by file-attributes).  Emacs uses this time to check stored local variables are still valid.  If you are assigning a class directly, not via a file, this argument should be nil.

 -- Variable: dir-locals-class-alist
     This alist holds the class symbols and the associated variable settings.  It is updated by dir-locals-set-class-variables.

 -- Variable: dir-locals-directory-cache
     This alist holds directory names, their assigned class names, and modification times of the associated directory local variables file (if there is one).  The function dir-locals-set-directory-class updates this list.

 -- Variable: enable-dir-local-variables
     If nil, directory-local variables are ignored.  This variable may be useful for modes that want to ignore directory-locals while still respecting file-local variables (see File Local Variables).

Connection Local Variables
==========================

Connection-local variables provide a general mechanism for different variable settings in buffers with a remote connection.  They are bound and set depending on the remote connection a buffer is dedicated to.

 -- Function: connection-local-set-profile-variables profile variables
     This function defines a set of variable settings for the connection PROFILE, which is a symbol.  You can later assign the connection profile to one or more remote connections, and Emacs will apply those variable settings to all process buffers for those connections.  The list in VARIABLES is an alist of the form (NAME . VALUE).  Example:

          (connection-local-set-profile-variables
            'remote-bash
            '((shell-file-name . "/bin/bash")
              (shell-command-switch . "-c")
              (shell-interactive-switch . "-i")
              (shell-login-switch . "-l")))

          (connection-local-set-profile-variables
            'remote-ksh
            '((shell-file-name . "/bin/ksh")
              (shell-command-switch . "-c")
              (shell-interactive-switch . "-i")
              (shell-login-switch . "-l")))

          (connection-local-set-profile-variables
            'remote-null-device
            '((null-device . "/dev/null")))

     If you want to append variable settings to an existing profile, you could use the function connection-local-get-profile-variables in order to retrieve the existing settings, like

          (connection-local-set-profile-variables
            'remote-bash
            (append
             (connection-local-get-profile-variables 'remote-bash)
             '((shell-command-dont-erase-buffer . t))))

 -- User Option: connection-local-profile-alist
     This alist holds the connection profile symbols and the associated variable settings.  It is updated by connection-local-set-profile-variables.

 -- Function: connection-local-set-profiles criteria &rest profiles
     This function assigns PROFILES, which are symbols, to all remote connections identified by CRITERIA.  CRITERIA is a plist identifying a connection and the application using this connection. Property names might be :application, :protocol, :user and :machine.  The property value of :application is a symbol, all other property values are strings.  All properties are optional; if CRITERIA is nil, it always applies.  Example:

          (connection-local-set-profiles
            '(:application 'tramp :protocol "ssh" :machine "localhost")
            'remote-bash 'remote-null-device)

          (connection-local-set-profiles
            '(:application 'tramp :protocol "sudo"
              :user "root" :machine "localhost")
            'remote-ksh 'remote-null-device)

     If CRITERIA is nil, it applies for all remote connections. Therefore, the example above would be equivalent to

          (connection-local-set-profiles
            '(:application 'tramp :protocol "ssh" :machine "localhost")
            'remote-bash)

          (connection-local-set-profiles
            '(:application 'tramp :protocol "sudo"
              :user "root" :machine "localhost")
            'remote-ksh)

          (connection-local-set-profiles
            nil 'remote-null-device)

     Any connection profile of PROFILES must have been already defined by connection-local-set-profile-variables.

 -- User Option: connection-local-criteria-alist
     This alist contains connection criteria and their assigned profile names.  The function connection-local-set-profiles updates this list.

 -- Function: hack-connection-local-variables criteria
     This function collects applicable connection-local variables associated with CRITERIA in connection-local-variables-alist, without applying them. Example:

          (hack-connection-local-variables
            '(:application 'tramp :protocol "ssh" :machine "localhost"))

          connection-local-variables-alist
               => ((null-device . "/dev/null")
                  (shell-login-switch . "-l")
                  (shell-interactive-switch . "-i")
                  (shell-command-switch . "-c")
                  (shell-file-name . "/bin/bash"))

 -- Function: hack-connection-local-variables-apply criteria
     This function looks for connection-local variables according to CRITERIA, and immediately applies them in the current buffer.

 -- Macro: with-connection-local-variables &rest body
     All connection-local variables, which are specified by default-directory, are applied.

     After that, BODY is executed, and the connection-local variables are unwound.  Example:

          (connection-local-set-profile-variables
            'remote-perl
            '((perl-command-name . "/usr/local/bin/perl")
              (perl-command-switch . "-e %s")))

          (connection-local-set-profiles
            '(:application 'tramp :protocol "ssh" :machine "remotehost")
            'remote-perl)

          (let ((default-directory "/ssh:remotehost:/working/dir/"))
            (with-connection-local-variables
              do something useful))

 -- Variable: connection-local-default-application
     The default application, a symbol, to be applied in with-connection-local-variables.  It defaults to tramp, but in case you want to overwrite Tramp's settings temporarily, you could let-bind it like

          (connection-local-set-profile-variables
            'my-remote-perl
            '((perl-command-name . "/usr/local/bin/perl5")
              (perl-command-switch . "-e %s")))

          (connection-local-set-profiles
            '(:application 'my-app :protocol "ssh" :machine "remotehost")
            'my-remote-perl)

          (let ((default-directory "/ssh:remotehost:/working/dir/")
                (connection-local-default-application 'my-app))
            (with-connection-local-variables
              do something useful))

     This variable must not be changed globally.

 -- Variable: enable-connection-local-variables
     If nil, connection-local variables are ignored.  This variable shall be changed temporarily only in special modes.

Variable Aliases
================

It is sometimes useful to make two variables synonyms, so that both variables always have the same value, and changing either one also changes the other.  Whenever you change the name of a variable---either because you realize its old name was not well chosen, or because its meaning has partly changed---it can be useful to keep the old name as an alias of the new one for compatibility.  You can do this with defvaralias.

 -- Function: defvaralias new-alias base-variable &optional docstring
     This function defines the symbol NEW-ALIAS as a variable alias for symbol BASE-VARIABLE. This means that retrieving the value of NEW-ALIAS returns the value of BASE-VARIABLE, and changing the value of NEW-ALIAS changes the value of BASE-VARIABLE.  The two aliased variable names always share the same value and the same bindings.

     If the DOCSTRING argument is non-nil, it specifies the documentation for NEW-ALIAS; otherwise, the alias gets the same documentation as BASE-VARIABLE has, if any, unless BASE-VARIABLE is itself an alias, in which case NEW-ALIAS gets the documentation of the variable at the end of the chain of aliases.

     This function returns BASE-VARIABLE.

Variable aliases are convenient for replacing an old name for a variable with a new name.  make-obsolete-variable declares that the old name is obsolete and therefore that it may be removed at some stage in the future.

 -- Function: make-obsolete-variable obsolete-name current-name when &optional access-type
     This function makes the byte compiler warn that the variable OBSOLETE-NAME is obsolete.  If CURRENT-NAME is a symbol, it is the variable's new name; then the warning message says to use CURRENT-NAME instead of OBSOLETE-NAME.  If CURRENT-NAME is a string, this is the message and there is no replacement variable.  WHEN should be a string indicating when the variable was first made obsolete (usually a version number string).

     The optional argument ACCESS-TYPE, if non-nil, should specify the kind of access that will trigger obsolescence warnings; it can be either get or set.

You can make two variables synonyms and declare one obsolete at the same time using the macro define-obsolete-variable-alias.

 -- Macro: define-obsolete-variable-alias obsolete-name current-name &optional when docstring
     This macro marks the variable OBSOLETE-NAME as obsolete and also makes it an alias for the variable CURRENT-NAME.  It is equivalent to the following:

          (defvaralias OBSOLETE-NAME CURRENT-NAME DOCSTRING)
          (make-obsolete-variable OBSOLETE-NAME CURRENT-NAME WHEN)

     This macro evaluates all its parameters, and both OBSOLETE-NAME and CURRENT-NAME should be symbols, so a typical usage would look like:

          (define-obsolete-variable-alias 'foo-thing 'bar-thing "27.1")

 -- Function: indirect-variable variable
     This function returns the variable at the end of the chain of aliases of VARIABLE.  If VARIABLE is not a symbol, or if VARIABLE is not defined as an alias, the function returns VARIABLE.

     This function signals a cyclic-variable-indirection error if there is a loop in the chain of symbols.

     (defvaralias 'foo 'bar)
     (indirect-variable 'foo)
          => bar
     (indirect-variable 'bar)
          => bar
     (setq bar 2)
     bar
          => 2

     foo
          => 2

     (setq foo 0)
     bar
          => 0
     foo
          => 0

Variables with Restricted Values
================================

Ordinary Lisp variables can be assigned any value that is a valid Lisp object.  However, certain Lisp variables are not defined in Lisp, but in C.  Most of these variables are defined in the C code using DEFVAR_LISP.  Like variables defined in Lisp, these can take on any value.  However, some variables are defined using DEFVAR_INT or DEFVAR_BOOL.  See Writing Emacs Primitives, in particular the description of functions of the type syms_of_FILENAME, for a brief discussion of the C implementation.

Variables of type DEFVAR_BOOL can only take on the values nil or t.  Attempting to assign them any other value will set them to t:

     (let ((display-hourglass 5))
       display-hourglass)
          => t

 -- Variable: byte-boolean-vars
     This variable holds a list of all variables of type DEFVAR_BOOL.

Variables of type DEFVAR_INT can take on only integer values. Attempting to assign them any other value will result in an error:

     (setq undo-limit 1000.0)
     error--> Wrong type argument: integerp, 1000.0

Generalized Variables
=====================

A generalized variable or place form is one of the many places in Lisp memory where values can be stored using the setf macro (see Setting Generalized Variables).  The simplest place form is a regular Lisp variable.  But the CARs and CDRs of lists, elements of arrays, properties of symbols, and many other locations are also places where Lisp values get stored.

Generalized variables are analogous to lvalues in the C language, where x = a[i] gets an element from an array and a[i] = x stores an element using the same notation. Just as certain forms like a[i] can be lvalues in C, there is a set of forms that can be generalized variables in Lisp.

The setf Macro
--------------

The setf macro is the most basic way to operate on generalized variables.  The setf form is like setq, except that it accepts arbitrary place forms in the first (left) argument of each pair rather than just symbols.  For example, (setf (car a) b) sets the car of a to b, doing the same operation as (setcar a b), but without you having to use two separate functions for setting and accessing this type of place.

 -- Macro: setf [place form]...
     This macro evaluates FORM and stores its value in PLACE, which must be a valid generalized variable form.  If there are several PLACE and FORM pairs, the assignments are done sequentially just as with setq.  setf returns the value of the last FORM.

The following Lisp forms are the forms in Emacs that will work as generalized variables, and so may appear in the PLACE argument of setf:

  * A symbol.  In other words, (setf x y) is exactly equivalent to (setq x y), and setq itself is strictly speaking redundant given that setf exists.  Most programmers will continue to prefer setq for setting simple variables, though, for stylistic and historical reasons.  The macro (setf x y) actually expands to (setq x y), so there is no performance penalty for using it in compiled code.

  * A call to any of the following standard Lisp functions:

          aref      cddr      symbol-function
          car       elt       symbol-plist
          caar      get       symbol-value
          cadr      gethash
          cdr       nth
          cdar      nthcdr

  * A call to any of the following Emacs-specific functions:

          alist-get                     overlay-start
          default-value                 overlay-get
          face-background               process-buffer
          face-font                     process-filter
          face-foreground               process-get
          face-stipple                  process-sentinel
          face-underline-p              terminal-parameter
          file-modes                    window-buffer
          frame-parameter               window-dedicated-p
          frame-parameters              window-display-table
          get-register                  window-hscroll
          getenv                        window-parameter
          keymap-parent                 window-point
          match-data                    window-start
          overlay-end

  * A call of the form (substring SUBPLACE N [M]), where SUBPLACE is itself a valid generalized variable whose current value is a string, and where the value stored is also a string.  The new string is spliced into the specified part of the destination string.  For example:

          (setq a (list "hello" "world"))
               => ("hello" "world")
          (cadr a)
               => "world"
          (substring (cadr a) 2 4)
               => "rl"
          (setf (substring (cadr a) 2 4) "o")
               => "o"
          (cadr a)
               => "wood"
          a
               => ("hello" "wood")

setf signals an error if you pass a PLACE form that it does not know how to handle.

Note that for nthcdr, the list argument of the function must itself be a valid PLACE form.  For example, (setf (nthcdr 0 foo) 7) will set foo itself to 7.

The macros push (see List Variables) and pop (see List Elements) can manipulate generalized variables, not just lists.  (pop PLACE) removes and returns the first element of the list stored in PLACE.  It is analogous to (prog1 (car PLACE) (setf PLACE (cdr PLACE))), except that it takes care to evaluate all subforms only once. (push X PLACE) inserts X at the front of the list stored in PLACE.  It is analogous to (setf PLACE (cons X PLACE)), except for evaluation of the subforms.  Note that push and pop on an nthcdr place can be used to insert or delete at any position in a list.

The cl-lib library defines various extensions for generalized variables, including additional setf places. See Generalized Variables (Common Lisp Extensions).

Defining new setf forms
-----------------------

This section describes how to define new forms that setf can operate on.

 -- Macro: gv-define-simple-setter name setter &optional fix-return
     This macro enables you to easily define setf methods for simple cases.  NAME is the name of a function, macro, or special form. You can use this macro whenever NAME has a directly corresponding SETTER function that updates it, e.g., (gv-define-simple-setter car setcar).

     This macro translates a call of the form

          (setf (NAME ARGS...) VALUE)

     into

          (SETTER ARGS... VALUE)

     Such a setf call is documented to return VALUE.  This is no problem with, e.g., car and setcar, because setcar returns the value that it set.  If your SETTER function does not return VALUE, use a non-nil value for the FIX-RETURN argument of gv-define-simple-setter.  This expands into something equivalent to

          (let ((temp VALUE))
            (SETTER ARGS... temp)
            temp)

     so ensuring that it returns the correct result.

 -- Macro: gv-define-setter name arglist &rest body
     This macro allows for more complex setf expansions than the previous form.  You may need to use this form, for example, if there is no simple setter function to call, or if there is one but it requires different arguments to the place form.

     This macro expands the form (setf (NAME ARGS...) VALUE) by first binding the setf argument forms (VALUE ARGS...) according to ARGLIST, and then executing BODY.  BODY should return a Lisp form that does the assignment, and finally returns the value that was set.  An example of using this macro is:

          (gv-define-setter caar (val x) `(setcar (car ,x) ,val))

 -- Macro: gv-define-expander name handler
     For more control over the expansion, the gv-define-expander macro can be used.  For instance, a settable substring could be implemented this way:

          (gv-define-expander substring
            (lambda (do place from &optional to)
              (gv-letplace (getter setter) place
                (macroexp-let2* (from to)
                  (funcall do `(substring ,getter ,from ,to)
                           (lambda (v)
                             (macroexp-let2* (v)
                               `(progn
                                  ,(funcall setter `(cl--set-substring
                                                     ,getter ,from ,to ,v))
                                  ,v))))))))

 -- Macro: gv-letplace (getter setter) place &rest body
     The macro gv-letplace can be useful in defining macros that perform similarly to setf; for example, the incf macro of Common Lisp could be implemented this way:

          (defmacro incf (place &optional n)
            (gv-letplace (getter setter) place
              (macroexp-let2* ((v (or n 1)))
                (funcall setter `(+ ,v ,getter)))))

     GETTER will be bound to a copyable expression that returns the value of PLACE.  SETTER will be bound to a function that takes an expression V and returns a new expression that sets PLACE to V.  BODY should return a Emacs Lisp expression manipulating PLACE via GETTER and SETTER.

Consult the source file gv.el for more details.

 -- Function: make-obsolete-generalized-variable obsolete-name current-name when
     This function makes the byte compiler warn that the generalized variable OBSOLETE-NAME is obsolete.  If CURRENT-NAME is a symbol, then the warning message says to use CURRENT-NAME instead of OBSOLETE-NAME.  If CURRENT-NAME is a string, this is the message.  WHEN should be a string indicating when the variable was first made obsolete (usually a version number string).

     Common Lisp note: Common Lisp defines another way to specify the setf behavior of a function, namely setf functions, whose names are lists (setf NAME) rather than symbols. For example, (defun (setf foo) ...) defines the function that is used when setf is applied to foo.  Emacs does not support this.  It is a compile-time error to use setf on a form that has not already had an appropriate expansion defined.  In Common Lisp, this is not an error since the function (setf FUNC) might be defined later.

Multisession Variables
======================

When you set a variable to a value and then close Emacs and restart it, that value won't be automatically restored.  Users usually set normal variables in their startup files, or use Customize (see Customization) to set user options permanently, and various packages have various files where they store the data (e.g., Gnus stores this in .newsrc.eld and the URL library stores cookies in ~/.emacs.d/url/cookies).

For things in between these two extremes (i.e., configuration which goes in the startup file, and massive application state that goes into separate files), Emacs provides a facility to replicate data between sessions called multisession variables.  (This facility may not be available on all systems.)  To give you an idea of how these are meant to be used, here's a small example:

     (define-multisession-variable foo-var 0)
     (defun my-adder (num)
       (interactive "nAdd number: ")
       (setf (multisession-value foo)
             (+ (multisession-value foo) num))
       (message "The new number is: %s" (multisession-value foo)))

This defines the variable foo-var and binds it to a special multisession object which is initialized with the value 0 (if the variable doesn't already exist from a previous session).  The my-adder command queries the user for a number, adds this to the old (possibly saved value), and then saves the new value.

This facility isn't meant to be used for huge data structures, but should be performant for most values.

 -- Macro: define-multisession-variable name initial-value &optional doc &rest args
     This macro defines NAME as a multisession variable, and gives it the INITIAL-VALUE if this variable hasn't been assigned a value earlier.  DOC is the doc string, and several keyword arguments can be used in ARGS:

     :package PACKAGE-SYMBOL
          This keyword says that a multisession variable belongs to the package specified by PACKAGE-SYMBOL.  The combination of PACKAGE-SYMBOL and NAME has to be unique.  If PACKAGE-SYMBOL isn't given, this will default to the first ``segment'' of the NAME symbol's name, which is the part of its name up to and excluding the first -.  For instance, if NAME is foo-var and PACKAGE-SYMBOL isn't given, PACKAGE-SYMBOL will default to foo.

     :synchronized BOOL
          Multisession variables can be synchronized if BOOL is non-nil.  This means that if there're two concurrent Emacs instances running, and the other Emacs changes the multisession variable foo-var, the current Emacs instance will retrieve that modified data when accessing the value.  If SYNCHRONIZED is nil or missing, this won't happen, and the values in all Emacs sessions using the variable will be independent of each other.

     :storage STORAGE
          Use the specified STORAGE method.  This can be either sqlite (in Emacs compiled with SQLite support) or files. If not given, this defaults to the value of the multisession-storage variable, described below.

 -- Function: multisession-value variable
     This function returns the current value of VARIABLE.  If this variable hasn't been accessed before in this Emacs session, or if it's changed externally, it will be read in from external storage.  If not, the current value in this session is returned as is.  It is an error to call this function for a VARIABLE that is not a multisession variable.

     Values retrieved via multisession-value may or may not be eq to each other, but they will always be equal.

     This is a generalized variable (see Generalized Variables), so the way to update such a variable is to say, for instance:

          (setf (multisession-value foo-bar) 'zot)

     Only Emacs Lisp values that have a readable print syntax (see Printed Representation) can be saved this way.

     If the multisession variable is synchronized, setting it may update the value first.  For instance:

          (cl-incf (multisession-value foo-bar))

     This first checks whether the value has changed in a different Emacs instance, retrieves that value, and then adds 1 to that value and stores it.  But note that this is done without locking, so if many instances are updating the value at the same time, it's unpredictable which instance ``wins''.

 -- Function: multisession-delete object
     This function deletes OBJECT and its value from its persistent storage.

 -- Function: make-multisession
     You can also make persistent values that aren't tied to a specific variable, but are tied to an explicit package and key.

          (setq foo (make-multisession :package "mail"
                                       :key "friends"))
          (setf (multisession-value foo) 'everybody)

     This supports the same keywords as define-multisession-variable, but also supports a :initial-value keyword, which specifies the default value.

 -- User Option: multisession-storage
     This variable controls how the multisession variables are stored.  It value defaults to files, which means that the values are stored in a one-file-per-variable structure inside the directory specified by multisession-directory.  If this value is sqlite instead, the values are stored in an SQLite database; this is only available if Emacs was built with SQLite support.

 -- User Option: multisession-directory
     The multisession variables are stored under this directory, which defaults to multisession/ subdirectory of the user-emacs-directory, which is typically ~/.emacs.d/multisession/.

 -- Command: list-multisession-values
     This command pops up a buffer listing all the multisession variables, and enters a special mode multisession-edit-mode which allows you to delete them and edit their values.