summaryrefslogtreecommitdiff
path: root/lisp/ledger-sort.el
blob: 206ffb940446c6c5411a5a9adb97cca214d3eef6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
;;; ledger-xact.el --- Helper code for use with the "ledger" command-line tool

;; Copyright (C) 2003-2013 John Wiegley (johnw AT gnu DOT org)

;; This file is not part of GNU Emacs.

;; This is free software; you can redistribute it and/or modify it under
;; the terms of the GNU General Public License as published by the Free
;; Software Foundation; either version 2, or (at your option) any later
;; version.
;;
;; This is distributed in the hope that it will be useful, but WITHOUT
;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
;; for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
;; MA 02111-1307, USA.



;;; Commentary:
;;

;;; Code:

(defun ledger-next-record-function ()
  "Move point to next transaction."
  (if (re-search-forward  ledger-payee-any-status-regex nil t)
      (goto-char (match-beginning 0))
      (goto-char (point-max))))

(defun ledger-end-record-function ()
  "Move point to end of transaction."
  (forward-paragraph))

(defun ledger-sort-find-start ()
  (if (re-search-forward ";.*Ledger-mode:.*Start sort" nil t)
      (match-end 0)))

(defun ledger-sort-find-end ()
  (if (re-search-forward ";.*Ledger-mode:.*End sort" nil t)
      (match-end 0)))

(defun ledger-sort-insert-start-mark ()
  (interactive)
  (save-excursion
    (goto-char (point-min))
    (if (ledger-sort-find-start)
	(delete-region (match-beginning 0) (match-end 0))))
  (beginning-of-line)
  (insert "\n; Ledger-mode: Start sort\n\n"))

(defun ledger-sort-insert-end-mark ()
  (interactive)
  (save-excursion
    (goto-char (point-min))
    (if (ledger-sort-find-end)
	(delete-region (match-beginning 0) (match-end 0))))
  (beginning-of-line)
  (insert "\n; Ledger-mode: End sort\n\n"))

(defun ledger-sort-startkey ()
  "Return the actual date so the sort-subr doesn't sort onthe entire first line."
  (buffer-substring-no-properties (point) (+ 10 (point))))

(defun ledger-sort-region (beg end)
  "Sort the region from BEG to END in chronological order."
  (interactive "r") ;; load beg and end from point and mark
  ;; automagically
  (let ((new-beg beg)
	(new-end end)
	point-delta
	(bounds (ledger-find-xact-extents (point)))
	target-xact)

    (setq point-delta (- (point) (car bounds)))
    (setq target-xact (buffer-substring (car bounds) (cadr bounds)))
    (setq inhibit-modification-hooks t)
    (save-excursion
      (save-restriction
	(goto-char beg)
	(ledger-next-record-function) ;; make sure point is at the
	;; beginning of a xact
	(setq new-beg (point))
	(goto-char end)
	(ledger-next-record-function) ;; make sure end of region is at
	;; the beginning of next record
	;; after the region
	(setq new-end (point))
	(narrow-to-region new-beg new-end)
	(goto-char new-beg)

	(let ((inhibit-field-text-motion t))
	  (sort-subr
	   nil
	   'ledger-next-record-function
	   'ledger-end-record-function
	   'ledger-sort-startkey))))

    (goto-char (point-min))
    (re-search-forward (regexp-quote target-xact))
    (goto-char (+ (match-beginning 0) point-delta))
    (setq inhibit-modification-hooks nil)))

(defun ledger-sort-buffer ()
  "Sort the entire buffer."
  (interactive)
  (let (sort-start
	sort-end)
    (save-excursion
      (goto-char (point-min))
      (setq sort-start (ledger-sort-find-start)
	    sort-end (ledger-sort-find-end)))
    (ledger-sort-region (if sort-start
			    sort-start
			    (point-min))
			(if sort-end
			    sort-end
			    (point-max)))))

(provide 'ledger-sort)

;;; ledger-sort.el ends here