1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
;;; yank-media.el --- Yanking images and HTML -*- lexical-binding:t -*-
;; Copyright (C) 2021 Free Software Foundation, Inc.
;; Author: Lars Ingebrigtsen <larsi@gnus.org>
;; Keywords: utility
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;;; Code:
(require 'cl-lib)
(defvar yank-media--registered-handlers nil)
;;;###autoload
(defun yank-media ()
"Yank media (images, HTML and the like) from the clipboard.
This command depends on the current major mode having support for
accepting the media type. The mode has to register itself using
the `register-yank-media-handler' mechanism."
(interactive)
(unless yank-media--registered-handlers
(user-error "The `%s' mode hasn't registered any handlers" major-mode))
(catch 'found
(pcase-dolist (`(,handled-type . ,handler)
yank-media--registered-handlers)
(when-let ((types (yank-media--find-matching-media handled-type)))
;; We have a handler in the current buffer; if there's just
;; matching type, just call the handler.
(if (length= types 1)
(funcall handler (car types)
(yank-media--get-selection (car types)))
;; More than one type the user for what type to insert.
(let ((type
(intern
(completing-read "Several types available, choose one: "
types nil t))))
(funcall handler type (yank-media--get-selection type))))
(throw 'found nil)))
(user-error
"No handler in the current buffer for anything on the clipboard")))
(defun yank-media--find-matching-media (handled-type)
(seq-filter
(lambda (type)
(pcase-let ((`(,major ,minor) (split-string (symbol-name type) "/")))
(if (and (equal major "image")
(not (image-type-available-p (intern minor))))
;; Just filter out all the image types that Emacs doesn't
;; support, because the clipboard is full of things like
;; `image/x-win-bitmap'.
nil
;; Check that the handler wants this type.
(and (if (symbolp handled-type)
(eq handled-type type)
(string-match-p handled-type (symbol-name type)))
;; An element may be in TARGETS but be empty.
(yank-media--get-selection type)))))
(gui-get-selection 'CLIPBOARD 'TARGETS)))
(defun yank-media--get-selection (type)
(when-let ((data (gui-get-selection 'CLIPBOARD type)))
(if-let ((charset (get-text-property 0 'charset data)))
(encode-coding-string data charset)
data)))
;;;###autoload
(defun register-yank-media-handler (types handler)
"Register HANDLER for dealing with `yank-media' actions for TYPES.
TYPES should be a MIME media type symbol, a regexp, or a list
that can contain both symbols and regexps."
(make-local-variable 'yank-media--registered-handlers)
(dolist (type (ensure-list types))
(setf (alist-get type yank-media--registered-handlers nil nil #'equal)
handler)))
(provide 'yank-media)
;;; yank-media.el ends here
|
