Build fixes for FetchContent users (#1974)

* Rename WABT_MASTER_PROJECT to PROJECT_IS_TOP_LEVEL

When WABT eventually upgrades to CMake 3.21+, only the one line setting
PROJECT_IS_TOP_LEVEL will need to be deleted.

* Add WABT_INSTALL_RULES option

This option is enabled by default when WABT is the top-level project and
disabled by default when it is not. It is used (and should continue to
be used) to guard uses of the install() command.

This fixes an issue where FetchContent users were forced to install
parts of WABT. This most notably included the wasm-rt-impl library and
its associated headers.

* Remove redundant defaults from install rules

CMake 3.14 changed the behavior of the install() command to take its
defaults from the GNUInstallDirs module. Use this feature to remove dead
code from the build.

* Deleted top-level cmake/ folder

There was nothing in here besides a README that referred to a find
module that no longer exists in the repository. Removing to avoid
confusion.

* Add components to install() rules

By default, CMake assigns every install() rule to an "Unspecified"
component. By adding COMPONENT annotations, users become empowered to
install only the parts of WABT that they need. WABT now provides three
components:

  1. wabt-runtime - the executables in WABT_EXECUTABLES
  2. wabt-development - the wasm-rt static library and headers
  3. wabt-documentation - the man pages, on UNIX only

Users can access this functionality using, e.g.:

    cmake --install build --component wabt-development

When a user specifies no component, all are installed.

FetchContent users benefit as well. If they enable WABT's install rules,
they can build accurate packaging dependencies around these components.

1 files changed, 26 insertions, 18 deletions

diff --git a/CMakeLists.txt b/CMakeLists.txt
index a4e8e7e3..fb21d226 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -25,10 +25,7 @@ set(CMAKE_CXX_STANDARD_REQUIRED ON)
 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
 
 # Check if wabt is being used directly or via add_subdirectory, FetchContent, etc
-set(WABT_MASTER_PROJECT OFF)
-if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
-  set(WABT_MASTER_PROJECT ON)
-endif()
+string(COMPARE EQUAL "${CMAKE_CURRENT_SOURCE_DIR}" "${CMAKE_SOURCE_DIR}" PROJECT_IS_TOP_LEVEL)
 
 # For git users, attempt to generate a more useful version string
 if (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/.git)
@@ -43,9 +40,9 @@ if (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/.git)
               GIT_VERSION
           OUTPUT_STRIP_TRAILING_WHITESPACE)
   if (${GIT_VERSION_RESULT})
-    # Don't issue warning if we aren't the master project;
+    # Don't issue warning if we aren't the top-level project;
     # just assume that whoever included us knows the version they are getting
-    if (WABT_MASTER_PROJECT)
+    if (PROJECT_IS_TOP_LEVEL)
       message(WARNING "${GIT_VERSION_ERROR} Error running git describe to determine version")
     endif()
   else ()
@@ -69,6 +66,7 @@ option(USE_UBSAN "Use undefined behavior sanitizer" OFF)
 option(CODE_COVERAGE "Build with code coverage enabled" OFF)
 option(WITH_EXCEPTIONS "Build with exceptions enabled" OFF)
 option(WERROR "Build with warnings as errors" OFF)
+option(WABT_INSTALL_RULES "Include WABT's install() rules" "${PROJECT_IS_TOP_LEVEL}")
 # WASI support is still a work in progress.
 # Only a handful of syscalls are supported at this point.
 option(WITH_WASI "Build WASI support via uvwasi" OFF)
@@ -360,8 +358,17 @@ add_library(wabt STATIC ${WABT_LIBRARY_SRC})
 
 IF (NOT WIN32)
   add_library(wasm-rt-impl STATIC wasm2c/wasm-rt-impl.c wasm2c/wasm-rt-impl.h)
-  install(TARGETS wasm-rt-impl DESTINATION ${CMAKE_INSTALL_LIBDIR})
-  install(FILES wasm2c/wasm-rt.h wasm2c/wasm-rt-impl.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+  if (WABT_INSTALL_RULES)
+    install(
+      TARGETS wasm-rt-impl
+      COMPONENT wabt-development
+    )
+    install(
+      FILES "wasm2c/wasm-rt-impl.h" "wasm2c/wasm-rt.h"
+      TYPE INCLUDE
+      COMPONENT wabt-development
+    )
+  endif ()
 endif ()
 
 if (BUILD_FUZZ_TOOLS)
@@ -689,17 +696,18 @@ if (BUILD_TESTS)
 endif ()
 
 # install
-if (BUILD_TOOLS OR BUILD_TESTS)
-  install(TARGETS ${WABT_EXECUTABLES} DESTINATION bin)
+if (WABT_INSTALL_RULES AND (BUILD_TOOLS OR BUILD_TESTS))
+  install(
+    TARGETS ${WABT_EXECUTABLES}
+    COMPONENT wabt-runtime
+  )
   if (UNIX)
-    if (NOT CMAKE_INSTALL_MANDIR)
-      include(GNUInstallDirs)
-    endif ()
-    file(GLOB MAN_FILES "${CMAKE_CURRENT_SOURCE_DIR}/man/*.1")
-    foreach(MAN_FILE ${MAN_FILES})
-      install(FILES ${MAN_FILE}
-        DESTINATION ${CMAKE_INSTALL_MANDIR}/man1/)
-    endforeach()
+    install(
+      DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/man/"
+      DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
+      COMPONENT wabt-documentation
+      FILES_MATCHING PATTERN "*.1"
+    )
   endif ()
 endif ()